mirror of
https://github.com/praktimarc/kst4contest.git
synced 2026-10-19 13:53:01 +02:00
Rsclub2_2
a6fba12f01
Etappen 1 and 2 of the Compose migration (43 commits). The Maven build, the single source tree and the JPMS module-info went together. core now holds the domain and app-desktop the user interface, both built by Gradle, packaged through jpackage from Gradle, with SpotBugs and PMD wired in. JavaFX moves to the classpath, which is why the launcher is Main and not the Application subclass. The PR check, the nightly artifacts, the release and the AUR packages all build from Gradle; the macOS DMG points at its output. Verified on Linux, macOS and Windows. core then loses JavaFX entirely. It observes through kst4contest.observe -- ObservableValue, ObservableRoster, and UiDispatcher as the one boundary a worker thread crosses to touch the interface. The controller collections become rosters and the visible station list a pure derivation rather than a FilteredList/SortedList chain, which is also what fixed two focus defects only a load test had exposed: the keyboard focus stays where the operator put it, and the send field keeps it after a row click. The rule that outlives this commit: ObservableRoster is the store and the list a view is bound to is a mirror of it, never the other way round.
46 lines
1.1 KiB
Kotlin
46 lines
1.1 KiB
Kotlin
plugins {
|
|
java
|
|
alias(libs.plugins.spotbugs) apply false
|
|
}
|
|
|
|
allprojects {
|
|
group = providers.gradleProperty("group").get()
|
|
version = providers.gradleProperty("version").get()
|
|
|
|
repositories {
|
|
mavenCentral()
|
|
}
|
|
}
|
|
|
|
val pmdVersion = libs.versions.pmd.get()
|
|
val spotbugsVersion = libs.versions.spotbugs.get()
|
|
|
|
subprojects {
|
|
apply(plugin = "java")
|
|
apply(plugin = "com.github.spotbugs")
|
|
apply(plugin = "pmd")
|
|
|
|
// Both tools report only; the Maven build had the failing goals commented out.
|
|
extensions.configure<PmdExtension> {
|
|
toolVersion = pmdVersion
|
|
ruleSetFiles = files(rootProject.file("pmd-ruleset.xml"))
|
|
ruleSets = emptyList()
|
|
isIgnoreFailures = true
|
|
}
|
|
|
|
extensions.configure<com.github.spotbugs.snom.SpotBugsExtension> {
|
|
toolVersion.set(spotbugsVersion)
|
|
ignoreFailures.set(true)
|
|
}
|
|
|
|
extensions.configure<JavaPluginExtension> {
|
|
toolchain {
|
|
languageVersion.set(JavaLanguageVersion.of(21))
|
|
}
|
|
}
|
|
|
|
tasks.withType<Test>().configureEach {
|
|
useJUnitPlatform()
|
|
}
|
|
}
|