Build with Gradle in two modules, and free core of JavaFX

Etappen 1 and 2 of the Compose migration (43 commits).

The Maven build, the single source tree and the JPMS module-info went together.
core now holds the domain and app-desktop the user interface, both built by
Gradle, packaged through jpackage from Gradle, with SpotBugs and PMD wired in.
JavaFX moves to the classpath, which is why the launcher is Main and not the
Application subclass. The PR check, the nightly artifacts, the release and the
AUR packages all build from Gradle; the macOS DMG points at its output.
Verified on Linux, macOS and Windows.

core then loses JavaFX entirely. It observes through kst4contest.observe --
ObservableValue, ObservableRoster, and UiDispatcher as the one boundary a
worker thread crosses to touch the interface. The controller collections become
rosters and the visible station list a pure derivation rather than a
FilteredList/SortedList chain, which is also what fixed two focus defects only
a load test had exposed: the keyboard focus stays where the operator put it,
and the send field keeps it after a row click.

The rule that outlives this commit: ObservableRoster is the store and the list
a view is bound to is a mirror of it, never the other way round.

app-desktop/build.gradle.kts

@@ -0,0 +1,70 @@
+plugins {
+    java
+    application
+    alias(libs.plugins.javafx)
+}
+
+javafx {
+    version = libs.versions.javafx.get()
+    modules = listOf("javafx.controls", "javafx.fxml", "javafx.web", "javafx.media")
+}
+
+dependencies {
+    // Mirrors the compile-scope entries in pom.xml: 11 test classes live under
+    // src/main/java and need JUnit and Mockito on the main compile classpath.
+    implementation(libs.junit.jupiter.api)
+    implementation(libs.mockito.core.compile)
+    implementation(libs.jetbrains.annotations)
+    implementation(project(":core"))
+    implementation(libs.sqlite.jdbc)
+    implementation(libs.jlayer)
+    testImplementation(libs.junit.jupiter)
+    testImplementation(libs.mockito.core)
+    testImplementation(libs.mockito.junit.jupiter)
+    // Gradle 9 no longer adds the launcher implicitly.
+    testRuntimeOnly(libs.junit.platform.launcher)
+}
+
+application {
+    mainClass.set("kst4contest.view.Kst4ContestApplication")
+}
+
+// Collects the application jar and its runtime dependencies into the layout the
+// packaging scripts expect: a flat directory with the main jar named app.jar.
+val collectRuntime by tasks.registering(Sync::class) {
+    dependsOn(tasks.jar)
+    from(tasks.jar) { rename { "app.jar" } }
+    from(configurations.runtimeClasspath)
+    into(layout.buildDirectory.dir("dist-libs"))
+}
+
+val packageImage by tasks.registering(Exec::class) {
+    dependsOn(collectRuntime)
+    // jpackage must come from the project toolchain, not from PATH: jdk.jsobject
+    // was removed after JDK 21, and jlink then cannot resolve the module list.
+    val launcher = javaToolchains.launcherFor {
+        languageVersion.set(JavaLanguageVersion.of(21))
+    }.get()
+    val jpackageTool = launcher.metadata.installationPath.file("bin/jpackage").asFile.absolutePath
+    val input = layout.buildDirectory.dir("dist-libs").get().asFile
+    val output = layout.buildDirectory.dir("jpackage").get().asFile
+    val os = org.gradle.internal.os.OperatingSystem.current()
+    val icon = when {
+        os.isWindows -> "packaging/icons/kst4contest.ico"
+        os.isMacOsX -> "packaging/icons/kst4contest.icns"
+        else -> "packaging/icons/kst4contest.png"
+    }
+    doFirst { output.deleteRecursively() }
+    commandLine(
+        jpackageTool,
+        "--icon", rootProject.file(icon).absolutePath,
+        "--type", "app-image",
+        "--name", "praktiKST",
+        "--input", input.absolutePath,
+        "--dest", output.absolutePath,
+        "--main-jar", "app.jar",
+        "--add-modules", providers.gradleProperty("jpackageAddModules").get(),
+        "--main-class", "kst4contest.view.Main",
+        "--java-options", "-Dfile.encoding=UTF-8"
+    )
+}